{
  description = "Jet Pham's personal website";
  inputs = {
    nixpkgs.url = "github:NixOS/nixpkgs/nixos-unstable";
    rust-overlay.url = "github:oxalica/rust-overlay";
    flake-utils.url = "github:numtide/flake-utils";
  };
  outputs = { self, nixpkgs, rust-overlay, flake-utils }:
    (flake-utils.lib.eachDefaultSystem (system:
      let
        overlays = [ (import rust-overlay) ];
        pkgs = import nixpkgs { inherit system overlays; };
        rustToolchain = pkgs.rust-bin.selectLatestNightlyWith (toolchain:
          toolchain.default.override {
            extensions = [ "rust-src" ];
            targets = [ "wasm32-unknown-unknown" ];
          });
        website = pkgs.stdenv.mkDerivation {
          pname = "jet-website";
          version = "0.1.0";
          src = pkgs.lib.cleanSource ./.;
          nativeBuildInputs = [ pkgs.nodejs rustToolchain pkgs.wasm-pack pkgs.binaryen pkgs.pkg-config ];
          buildPhase = ''
            export HOME=$TMPDIR
            cd cgol && wasm-pack build --release --target web && cd ..
            wasm-opt cgol/pkg/cgol_bg.wasm -o cgol/pkg/cgol_bg.wasm -O4 --enable-bulk-memory --enable-nontrapping-float-to-int --enable-sign-ext --low-memory-unused --converge
            npm ci
            npm run build
          '';
          installPhase = ''
            mkdir -p $out
            cp -r dist/* $out/
          '';
        };
      in {
        packages = { default = website; };
        devShells.default = pkgs.mkShell {
          buildInputs = with pkgs; [
            nodejs git curl typescript-language-server
            pkg-config wasm-pack binaryen rustToolchain
          ];
        };
      }
    )) // {
      nixosModules.default = import ./module.nix self;
    };
}