{
  description = "Noisebell remote services";

  inputs = {
    nixpkgs.url = "github:NixOS/nixpkgs/nixos-unstable";
    crane.url = "github:ipetkov/crane";
    rust-overlay = {
      url = "github:oxalica/rust-overlay";
      inputs.nixpkgs.follows = "nixpkgs";
    };
  };

  outputs = { self, nixpkgs, crane, rust-overlay }:
    let
      system = "x86_64-linux";
      pkgs = import nixpkgs {
        inherit system;
        overlays = [ rust-overlay.overlays.default ];
      };

      rustToolchain = pkgs.rust-bin.stable.latest.default;
      craneLib = (crane.mkLib pkgs).overrideToolchain rustToolchain;

      src = craneLib.cleanCargoSource ./.;

      commonArgs = {
        inherit src;
        pname = "noisebell";
        version = "0.1.0";
        strictDeps = true;
        doCheck = false;
      };

      cargoArtifacts = craneLib.buildDepsOnly commonArgs;

      buildMember = name: craneLib.buildPackage (commonArgs // {
        inherit cargoArtifacts;
        cargoExtraArgs = "-p ${name}";
      });

      noisebell-cache = buildMember "noisebell-cache";
      noisebell-discord = buildMember "noisebell-discord";
      noisebell-rss = buildMember "noisebell-rss";
    in
    {
      packages.${system} = {
        inherit noisebell-cache noisebell-discord noisebell-rss;
        default = noisebell-cache;
      };

      nixosModules = {
        cache = import ./cache-service/module.nix noisebell-cache;
        discord = import ./discord-bot/module.nix noisebell-discord;
        rss = import ./rss-service/module.nix noisebell-rss;
        default = { imports = [
          (import ./cache-service/module.nix noisebell-cache)
          (import ./discord-bot/module.nix noisebell-discord)
          (import ./rss-service/module.nix noisebell-rss)
        ]; };
      };

      devShells.${system}.default = craneLib.devShell {
        packages = [ pkgs.rust-analyzer ];
      };
    };
}